source: buchla-68k/iolib/rtraps.s@ ca867c1

Last change on this file since ca867c1 was 8325447, checked in by Thomas Lopatic <thomas@…>, 7 years ago

Removed _ prefix.
  • Property mode set to 100644
File size: 1.4 KB
Line 
1| ------------------------------------------------------------------------------
2| rtraps.s -- define ROMP debug trap
3| Version 7 -- 1988-01-12 -- Copyright 1987, 1988 by D.N. Lynx Crowe
4| ------------------------------------------------------------------------------
5 .text
6
7 .xdef trap15
8
9 .xref rompbp
10
11 .xref tr1sav,tr13sav,tr14sav
12 .xref tr1rmp,tr13rmp,tr14rmp
13
14BUCHLA = 1 | IPL value: 0 = NASA , 1 = Buchla
15
16 .ifeq BUCHLA
17IPLEVEL = 0x0400 | NASA IPL = 4 (enable 5 and above)
18 .endc
19
20 .ifne BUCHLA
21IPLEVEL = 0x0200 | Buchla IPL = 2 (enable 3 and above)
22 .endc
23
24IPL7 = 0x0700 | IPL 7
25
26| trap15 -- ROMP debug trap (used to implement breakpoints)
27| ------ ------------------------------------------------
28trap15: ori.w #IPL7,sr | Disable interrupts
29 move.w #0,-(a7) | Keep stack long aligned
30 movem.l d0-d7/a0-a7,-(a7) | Save regs on stack
31 move.l tr1sav,tr1rmp | Save trap save areas
32 move.l tr13sav,tr13rmp | ...
33 move.l tr14sav,tr14rmp | ...
34 move.w sr,d0 | Get status register
35 andi.w #0xF8FF,d0 | Enable serial I/O interrupts
36 ori.w #IPLEVEL,d0 | ...
37 move.w d0,sr | ...
38 jsr rompbp | Pass control to ROMP
39
40 ori.w #IPL7,sr | Disable interrupts
41 move.l tr14rmp,tr14sav | Restore trap save areas
42 move.l tr13rmp,tr13sav | ...
43 move.l tr1rmp,tr1sav | ...
44 movem.l (a7)+,d0-d7/a0-a7 | Restore regs
45 addq.l #2,a7 | Discard alignment filler word
46 rte | Back to what we interrupted
47
48 .end
Note: See TracBrowser for help on using the repository browser.